home *** CD-ROM | disk | FTP | other *** search
/ SPACE 1 / SPACE - Library 1 - Volume 1.iso / misc~1 / 5 / journey.bas < prev    next >
BASIC Source File  |  1985-11-19  |  18KB  |  346 lines
  1. 0     gosub 32000
  2. 1     fullw 2:clearw 2:gotoxy 20,6
  3. 2     poke contrl,106:poke contrl+2,0:poke contrl+6,1:poke intin,13:vdisy2,0:poke contrl+6,1:poke intin,4:vdisys(1)
  4. 7     ?:?
  5. 8     gotoxy 26,8:?" A 520ST Adventure"
  6. 9     poke contrl,106:poke contrl+2,0:poke contrl+6,1:poke intin,5:vdisys(1)
  7. 10    gotoxy 19,10:print"Converted to ST Basic by Rich Noe"
  8. 11    POKE CONTRL,106:POKE CONTRL+2,0:POKE CONTRL+6,1:POKE INTIN,1:VDISYS(1)
  9. 70    CP=1:GOSUB 1930
  10. 80    CLEARW 2:GOTOXY 0,0
  11. 90    GOSUB 1830:GOSUB 1720
  12. 100   IF CP=18 AND (VB<>25 OR NO<>21)THEN PRINT"Horrors!! The troll throws an axe at me!  I am dead":GOTO 1460
  13. 110   IF CP=18 THEN PRINT M2$:F5=1:GOSUB 1720
  14. 120   IF NO<23 OR VB>1 OR NO>30 THEN 210
  15. 130   IF NO<=26 THEN FD=FD+1 ELSE FD= -10000
  16. 140   IF NO>26 THEN NO=NO-4
  17. 150   NO=NO-22
  18. 160   IF CP=10 AND NO=1 THEN PRINT"And fall into the lava???  Fat chance!":GOSUB 1720:GOTO 120
  19. 170   IF CP=11 AND NO=2 THEN PRINT"Do you know what molten lava is???  It's hot, that's what!":GOSUB 1720:GOTO 120
  20. 180   IF CP=29 AND OB(10,0)=29 AND (NO=4 OR NO=2) THEN PRINT"The hydra won't let me through!":GOSUB 1720:GOTO 120
  21. 190   IF P(CP,NO)=0 THEN PRINT"I can't go THAT way!":GOSUB 1720:GOTO 120
  22. 200   CP=P(CP,NO):GOTO 80
  23. 210   IF VB<>2 AND VB<>20 THEN 290
  24. 220   IF NO=10 AND OB(33,0)=CP THEN PRINT"It is sort of heavy, you know.":GOSUB 1720:GOTO 120
  25. 230   IF NO=0 THEN PRINT"I don't know what a ";CHR$(34);NO$;CHR$(34);" is.":GOSUB 1720:GOTO 120
  26. 240   IF OB(NO,0)<>CP THEN PRINT"I don't see it here.":GOSUB 1720:GOTO 120
  27. 250   IF NO=10 OR NO=20 THEN PRINT"Oh give me a break!!":GOSUB 1720:GOTO 120
  28. 260   IF OB(NO,0)=-1 THEN PRINT"I'm already carrying it.":GOSUB 1720:GOTO 120
  29. 270   IF OB(NO,0)=CP AND NT>=6 THEN PRINT"I can't carry any more. You'll have to drop something.":GOSUB 1720:GOTO 120
  30. 280   IF OB(NO,0)=CP THEN PRINT"Check.":NT=NT+1:OB(NO,0)=-1:GOSUB 1720:GOTO 120
  31. 290   IF VB<>4 AND VB<>29 THEN 340
  32. 300   F3=0
  33. 310   PRINT"I am currently carrying :":FOR I=1 TO LO:IF OB(I,0)=-1 THEN PRINT OB$(I):F3=1
  34. 320   NEXT I:IF F3=0 THEN PRINT"Nothing."
  35. 330   GOSUB 1720:GOTO 120
  36. 340   IF VB=3 THEN 80
  37. 350   IF NO=0 AND VB=0 THEN PRINT"That doesn't make any sense to me.":GOSUB 1720:GOTO 120
  38. 360   IF VB<>5 THEN 420
  39. 370   J=0
  40. 380   FOR I=1 TO LO:IF OB(I,0)=1 THEN J=J+OB(I,1)
  41. 390   NEXT I:PRINT"Out of a maximum of 175 points, you have";J
  42. 400   IF J=0 THEN PRINT"Boy, you stink!"
  43. 410   GOSUB 1720:GOTO 120
  44. 420   IF VB<>6 AND VB<>22 THEN 490
  45. 430   IF NO$<>"Everything" AND NO$<>"All" THEN 470
  46. 440   FOR I=1 TO LO:IF OB(I,0)=-1 THEN OB(I,0)=CP
  47. 450   NEXT I:NT=0
  48. 460   PRINT"Okay.":GOSUB 1720:GOTO 120
  49. 470   IF OB(NO,0)<>-1 THEN PRINT"How can I drop what I am not holding???":GOSUB 1720:GOTO 120
  50. 480   OB(NO,0)=CP:PRINT"O.K.":NT=NT-1:GOSUB 1720:GOTO 120
  51. 490   IF VB<>7 AND VB<>28 THEN 530
  52. 500   IF H$(CP)="" THEN PRINT"You got me into this mess, now you get me out!"
  53. 510   PRINT H$(CP):H$(CP)=""
  54. 520   GOSUB 1720:GOTO 120
  55. 530   IF VB<>8 THEN 600
  56. 535   CLEARW 2:GOTOXY 0,0:?:PRINT:PRINT:PRINT TAB(10)," ";:INPUT"Filename";FILE$
  57. 540   CLEARW 2:GOTOXY 0,0 :INPUT"Press <RETURN> to save game";XX$:OPEN "O",1,FILE$
  58. 550   FOR I=1 TO LO:IF OB$(I)="" THEN 570
  59. 560   PRINT#1,OB(I,0),OB(I,1)
  60. 570   NEXT I
  61. 580   PRINT#1,CP:CLOSE
  62. 590   GOSUB 1720:GOTO 120
  63. 600   IF VB<>9 THEN 670
  64. 605   CLEARW 2:GOTOXY 0,0:PRINT:PRINT:PRINT TAB(10)," ";:INPUT"Filename";FILE$
  65. 610   CLEARW 2:GOTOXY 0,0:INPUT"Press <RETURN> to restore ";XX$:OPEN "I",1,FILE$
  66. 620   FOR I=1 TO LO:IF OB$(I)="" THEN 640
  67. 630   INPUT#1,OB(I,0),OB(I,1)
  68. 640   NEXT I
  69. 650   INPUT#1,CP:CLOSE
  70. 660   GOTO 80
  71. 670   IF VB<>10 THEN 690
  72. 680   GOTO 1470
  73. 690   IF VB<>11 THEN 720
  74. 700   IF NO=0 THEN PRINT"Say what?":GOSUB  1720:GOTO 120
  75. 710   PRINT"Okay, if it is really necessary...";NO$:GOSUB 1720:GOTO 120
  76. 720   IF VB<>12 THEN 760
  77. 730   IF NO<>12 THEN PRINT"I don't do stupid things.":GOSUB 1720:GOTO 120
  78. 740   IF OB(12,0)<>-1 THEN PRINT"I don't have any Coke to drink!":GOSUB 1720:GOTO 120
  79. 750   PRINT M3$:OB(12,0)=0:OB(13,0)=-1:GOSUB 1720:GOTO 120
  80. 760   IF VB<>13 THEN 830
  81. 770   IF OB(31,0)<>-1 THEN PRINT"But I have no food!!":GOSUB 1720:GOTO 120
  82. 780   IF OB(NO,0)<>CP THEN PRINT"I don't see it.":GOSUB 1720:GOTO 120
  83. 790   IF NO=10 THEN PRINT"The hydra whoofs down the food.":OB(31,0)=0:OB$(10)="a giant hydra rubbing his stomach":GOSUB 1720:GOTO 120
  84. 800   IF NO=20 THEN PRINT"The bugs in these caves only eat human flesh.":GOSUB 1720:GOTO 120
  85. 810   IF NO<>3 THEN PRINT"You can't be serious.":GOSUB 1720:GOTO 120
  86. 820   PRINT"It refuses to eat the food.":GOSUB 1720:GOTO 120
  87. 830   IF VB<>14 THEN 910
  88. 840   IF NO=10 AND OB(33,0)=CP THEN PRINT"The undertaker just took him away.":OB(33,0)=0:GOSUB 1720:GOTO 120
  89. 850   IF OB(NO,0)<>CP AND OB(NO,0)<>-1 THEN PRINT"I don't see it and I'm not holding ii, so how can I hit it?":GOSUB 1720:GOTO 120
  90. 860   IF NO=3 THEN PRINT"No!!!  I kind of like the parrot!  Polly want a cracker?"
  91. 870   IF NO=10 THEN PRINT"Okay...                                                                                The hydra grunts >>DAMN MOSQUITOS<<"
  92. 880   IF NO=20 THEN PRINT"Yuch!  I don't want to touch it!!!"
  93. 890   IF NO=30 OR NO=10 OR NO=20 THEN GOSUB 1720:GOTO 120
  94. 900   PRINT"Okay...    Ouch!  I hurt my hand!":GOSUB 1720:GOTO 120
  95. 910   IF VB=15 THEN PRINT"I can't kill anything, I'm too weak.  But maybe if you were a bit more specific.":GOSUB 1720:GOTO 120
  96. 920   IF VB<>16 THEN 1010
  97. 930   IF OB(33,0)=CP AND NO=10 THEN PRINT"It is already burnt to a crisp.":GOSUB 1720:GOTO 120
  98. 940   IF OB(6,0)<>-1 THEN PRINT"I don't have a lighter or matches!!":GOSUB 1720:GOTO 120
  99. 950   IF NO=3 THEN PRINT"Never!!  You know something, you're a sadist.":GOSUB 1720:GOTO 120
  100. 960   IF NO=10 AND OB(10,0)=CP THEN OB(10,0)=0:OB(33,0)=CP:PRINT"The hydra crumbles to the ground dead.":GOSUB 1720:GOTO 120
  101. 970   IF NO=20 THEN PRINT"The bug cannot be burnt.  <GULP>":GOSUB 1720:GOTO 120
  102. 980   IF NO=10 THEN OB(10,0)=0
  103. 990   PRINT"It doesn't burn."
  104. 1000  GOSUB 1720:GOTO 120
  105. 1010  IF VB=17 THEN PRINT"And just who do you think I am, Rocky???":GOSUB 1720:GOTO 120
  106. 1020  IF VB=18 THEN PRINT"I don't know how to light things.  If you want me to burn something, tell me so!":GOSUB 1720:GOTO 120
  107. 1030  IF VB<>19 THEN 1120
  108. 1040  IF NO$="COIN" THEN NO$="QUARTER":NO=7
  109. 1050  IF NO=0 THEN PRINT"I don't know what one is.":GOSUB 1720:GOTO 120
  110. 1060  IF NO=7 THEN 1080
  111. 1070  IF OB(NO,0)<>-1 THEN PRINT"I'm not holding it right now.":GOSUB 1720:GOTO 120
  112. 1080  IF CP<>27 THEN PRINT"I don't see any Coke machines here.":GOSUB 1720:GOTO 120
  113. 1090  IF NO<>7 THEN PRINT"That is ridiculous.":GOSUB 1720:GOTO 120
  114. 1100  IF OB(NO,0)<>-1 THEN PRINT"I have no money.":GOSUB 1720:GOTO 120
  115. 1110  IF OB(7,0)=-1 AND CP=27 THEN PRINT"All right.   Chikclik Chinggg!               A Coke popped out.  There is now a bottle of Coke here.":OB(7,0)=0:NT=NT-1:OB(12,0)=27:GOSUB 1720:GOTO 120
  116. 1120  REM
  117. 1130  IF VB<>21 THEN 1210
  118. 1140  IF NO<>18 AND OB(NO,0)=-1 THEN PRINT"It's kind of heavy, you know.":GOSUB 1720:GOTO 120
  119. 1150  IF OB(NO,0)<>-1 THEN PRINT"First you have to help me find it, dummy!":GOSUB 1720:GOTO 120
  120. 1160  IF CP=10 OR CP=11 THEN 1180
  121. 1170  PRINT"Nothing happened":GOSUB 1720:GOTO 120
  122. 1180  IF CP=10 THEN CP=11:GOTO 1200
  123. 1190  CP=10
  124. 1200  GOTO 80
  125. 1210  IF VB=23 THEN VB=1:GOTO 120
  126. 1220  IF VB=24 THEN PRINT"Try kill ";NO$:GOSUB 1720:GOTO 120
  127. 1230  IF VB<>25 THEN 1260
  128. 1240  IF NO=21 THEN PRINT"Nothing happened":GOSUB 1720:GOTO 120
  129. 1250  PRINT"Sir what???  I don't understand!":GOSUB 1720:GOTO 120
  130. 1260  IF VB<>26 THEN 1330
  131. 1270  IF CP=1 AND OB(14,0)=-1 AND OB(22,0)=1 THEN PRINT"Okay!!!":GOTO 1460
  132. 1280  IF CP<>1 THEN PRINT"I can't.":GOSUB 1720 :GOTO 120
  133. 1290  IF VB<>26 THEN 1330
  134. 1300  IF OB(14,0)<>-1 THEN PRINT"I can't.  I have no tools.":GOSUB 1720:GOTO 120
  135. 1310  PRINT"I can't.  I don't see the fribulating gonkulator around me.";:IF OB(22,0)=-1 THEN PRINT" I think I have to drop it first." ELSE PRINT
  136. 1320  GOSUB 1720:GOTO 120
  137. 1330  IF VB<>27 THEN 1410
  138. 1340  IF NO=0 THEN PRINT"What the devil is a ";NO$;"??":GOSUB 1720:GOTO 120
  139. 1350  IF NO=20 OR NO=10 THEN IF OB(NO,0)=CP THEN PRINT"Yuch!!!  I'd never eat a ";NO$;"!!!":GOSUB 1720:GOTO  120
  140. 1360  IF NO=10 AND OB(33,0)=CP THEN PRINT"Well...  It's cooked now, but it still looks kind of gross.":GOSUB 1720:GOTO 120
  141. 1370  IF OB(NO,0)<>-1 THEN PRINT"I'm not holding it.":GOSUB 1720 :GOTO 120
  142. 1380  IF NO=3 AND OB(3,0)=-1 THEN PRINT"I'd rather not.  I don't care for parrot meat.":GOSUB 1720:GOTO 120
  143. 1390  IF NO=31 AND OB(31,0)=-1 THEN NT=NT-1:PRINT"Humm!  It was Filet Mignon, my favorite dish.":OB(31,0)=0:GOSUB 1720:GOTO 120
  144. 1400  PRINT"I think that ";OB$(NO);" would give me indigestion, and I don't have any Pepto-Bismol.":GOSUB 1720:GOTO 120
  145. 1410  IF VB<>30 THEN 1450
  146. 1420  IF CP<>10 AND CP<>11 THEN PRINT"Nothing happened.":GOSUB 1720:GOTO 120
  147. 1430  PRINT"Nice try, but that's an old, worn out magic word."
  148. 1440  GOSUB 1720:GOTO 120
  149. 1450  PRINT"I don't know how to do that.":GOSUB 1720:GOTO 120
  150. 1460  FOR I=1 TO 1000:NEXT I
  151. 1470  PRINT"Out of a maximum of 175 points, you have scored";:J=0
  152. 1480  FOR I=1 TO LO:IF OB(I,0)=1 THEN J=J+OB(I,1)
  153. 1490  NEXT I
  154. 1500  PRINT J;" points."
  155. 1510  IF J=175 THEN ?"All give tribute to you, ADVENTURER GRANDMASTER":goto 1590
  156. 1520  IF J>165 THEN PRINT"Your score is Master Adventurer Class A.":GOTO 1590
  157. 1530  IF J>150 THEN PRINT"Your score is Master Adventurer Class B.":GOTO 1590
  158. 1540  IF J>140 THEN PRINT"You are";CHR$(34);"Junior Master";CHR$(34):goto 1590
  159. 1550  IF J>120 THEN PRINT"You are now a Seasoned Adventurer":goto 1590
  160. 1560  IF J>110 THEN ?"You have the rating: Experienced Adventurer":goto 1590
  161. 1570  IF J>100 THEN ?"Your score is a Novice Class Adventurer.":goto 1590
  162. 1580  PRINT"You are obviously a rank amateur.  Better luck next time."
  163. 1590  '
  164. 1600  END
  165. 1610  PRINT"GADZOOKS!!!  A giant bug just walked in to kill me!!!"
  166. 1620  FF=1
  167. 1630  GOSUB 1720
  168. 1640  IF NO$="Sesame" AND VB$="Open" THEN PRINT"The bug has shrunk to it's proper size and scurried away.":GOTO 1700
  169. 1650  IF NO<>20 OR VB<>15 THEN PRINT"HELP ME!!!  I'm being devoured by a giant bug!!!  The end is near!  OW!!  This hurts!!  I'm dying...dying...DEAD!!!":GOTO 1460
  170. 1660  IF OB(2,0)<>-1 THEN NO=2:PRINT"I don't have a sword!!!":GOTO 1650
  171. 1670  IF SW=8 THEN PRINT"My sword is dull, remember???":NO=2:GOTO 1650
  172. 1680  PRINT"Ding! Dong!  The bug is dead, the bug is dead!!!"
  173. 1690  SW=SW+1:IF SW=8 THEN PRINT"My sword is dull now."
  174. 1700  GOSUB 1720:GOTO 120
  175. 1710  END
  176. 1720  PRINT:INPUT"Enter your command";CM$:PRINT
  177. 1730  IF CM$="ABRA CADABRA" AND F5<3 AND FF=1 THEN NO$="SESAME":VB$="OPEN":FF=0:F5=F5+1:RETURN
  178. 1740  VB$="":NO$="":VB=0:NO=0
  179. 1750  LC=LEN(CM$):FOR I=1 TO LC
  180. 1754  IF MID$(CM$,I,1) >"0" THEN VB$=VB$+MID$(CM$,I,1) ELSE GOTO 1760
  181. 1755  NEXT I
  182. 1760  FOR I=1 TO NV:IF VB$(I)=VB$ THEN VB=I:GOTO 1780 ELSE NEXT I
  183. 1770  VB=0:NO$=VB$:GOTO 1800
  184. 1780  IF LEN(VB$)+1>=LEN(CM$) THEN NO=0: RETURN
  185. 1790  NO$=RIGHT$(CM$,LEN(CM$)-1-LEN(VB$))
  186. 1800  FOR I=1 TO NN:IF NO$(I)=NO$ THEN 1820 ELSE NEXT I
  187. 1810  NO=0:RETURN
  188. 1820  NO=I:RETURN
  189. 1830  PRINT P$(CP):PRINT
  190. 1840  FOR I=1 TO LO:IF OB(I,0)=CP THEN PRINT"There is ";OB$(I);" here.":PRINT
  191. 1850  NEXT I
  192. 1860  PRINT"I can go :     ";:F2=0
  193. 1870  FOR I=1 TO 4:IF P(CP,I)<>0 THEN PRINT NO$(I+22);"  ";:F2=1
  194. 1880  NEXT I:IF F2=0 THEN PRINT"Nowhere!"
  195. 1890  IF CP=18 AND OB(3,0)=-1 THEN PRINT:PRINT M1$
  196. 1900  IF RND(35)=5 AND CP<>1 AND CP<>37 AND CP<>27 THEN PRINT:GOTO 1610
  197. 1910  IF FD>4 THEN PRINT:PRINT"If you'd like, you can make it easy on yourself by typing                       N, S, E, or W instead of NORTH, SOUTH, etc.":FD=0
  198. 1920  RETURN
  199. 1930  NP=37:DIM P$(NP)
  200. 1940  REM
  201. 1950  P$(1)="I am in a ship.  On a computer screen in here it says:                          Ship will not function -- Fribulating Gonkulator is burned out.                  It is obvious that this ship has crashed."
  202. 1960  P$(2)="I'm in a cobblestone hallway.  I can hear CHIRPING BUGS NEARBY"
  203. 1965  DATA 2,6,5,4,8,1,3,5
  204. 1970  P$(3)="I'm in a dark room...OH NO!!! There are GIANT bugs all around me!!"
  205. 1975  DATA 0,0,0,2
  206. 1980  P$(4)="I'm in a small room.  A scribbling here says: >>ABBADAC ARBA <<"
  207. 1985  DATA 7,0,1,0
  208. 1990  P$(5)="I'm in a dusty cobblestone hallway"
  209. 1995  DATA 0,25,2,1
  210. 2000  P$(6)="I'm in a dusty place.  It is very dark in here  I'm scared!"
  211. 2005  DATA 1,24,0,0
  212. 2010  P$(7)="I'm in low crawl space.  It seems  we're not SUPPOSED to be here!"
  213. 2015  DATA 0,4,15,0
  214. 2020  P$(8)="I'm in a room with rock walls.  Imbedded in the walls are Rubies"
  215. 2025  DATA 9,2,0,13
  216. 2030  P$(9)="I'm in a dark room.  This one is not so scary. I hear groans"
  217. 2035  data 10,8,23,0
  218. 2040  P$(10)="I'm on the south side of a chasm.  Molten lava is beneath me."
  219. 2045  data 11,9,0,0
  220. 2050  P$(11)="I'm on the north side of the chasm."
  221. 2055  data 16,10,0,0
  222. 2060  P$(12)="I'm in a maze of twisty little passages."
  223. 2065  data 12,12,13,14
  224. 2070  P$(13)=P$(12)
  225. 2075  data 13,13,8,12
  226. 2080  P$(14)=P$(12)
  227. 2085  data 14,15,12,14
  228. 2090  P$(15)=P$(12)
  229. 2095  data 14,15,15,7
  230. 2100  P$(16)="on a wood platform.  A sign warns: Go back! Go S! weak bridge N"
  231. 2105  data 17,11,0,0
  232. 2110  P$(17)="dusty passage.  A sign points east and says:To TROLLS PLACE"
  233. 2115  data 0,16,18,0
  234. 2120  P$(18)="A voice booms out:Who dares enter my place (sounds like a TROLL"
  235. 2125  data 0,0,19,0
  236. 2130  P$(19)="I'm in the troll's palace.  It's breathtaking!!!"
  237. 2135  data 0,20,0,0
  238. 2140  P$(20)="I'm at one end of a secret passage."
  239. 2145  data 19,0,0,21
  240. 2150  P$(21)="I'm in a secret passage."
  241. 2155  data 21,22,20,21
  242. 2160  P$(22)=P$(21)
  243. 2165  data 21,22,22,23
  244. 2170  P$(23)=P$(21)
  245. 2175  data 23,23,22,9
  246. 2180  P$(24)="I'm in a huge ice cavern.  The ceiling and walls are all ice."
  247. 2185  data 6,26,25,0
  248. 2190  P$(25)="I'm in a room with many animals... Wait! They all ran away"
  249. 2195  data 5,0,0,0
  250. 2200  P$(26)="I'm in a room with traces of slime on the floor and walls."
  251. 2205  data 24,29,27,28
  252. 2210  P$(27)="I'm in Al's Diner???  There's a Coke machine. It says: Quarter "
  253. 2215  data 0,0,0,26
  254. 2220  P$(28)="I'm in a huge pit."
  255. 2230  DATA 0,0,26,0
  256. 2240  P$(29)="I'm in the hydra room.  The walls are all slime."
  257. 2245  DATA 26,30,31,32
  258. 2250  P$(30)="I'm in the dragon room.  It seems to decorated with dragons."
  259. 2255  data 29,34,0,33
  260. 2260  P$(31)="I'm in a torture chamber.  Let's get out of here quick!!"
  261. 2265  data 31,31,31,29
  262. 2270  P$(32)="This is the clam room.  The walls are solid clamshell"
  263. 2275  DATA 0,0,29,0
  264. 2280  P$(33)="I'm in a mammoth garden.  This is all plants."
  265. 2285  DATA 0,0,30,0
  266. 2290  P$(34)="I'm in the velvet room.  The walls and ceiling are velvet."
  267. 2295  DATA 30,34,35,0
  268. 2300  P$(35)="I'm in an Arabian room. ther is a machine oil slick nearby"
  269. 2305  DATA 36,37,0,34
  270. 2310  P$(36)="Treasure room.dwarfs guard some treasure.Nothing to flip over"
  271. 2315  DATA 0,35,0,0
  272. 2320  P$(37)="I'm at Mac's Earthdigger Bodyshop."
  273. 2325  DATA 35,0,0,0
  274. 2330  DIM P(37,4)
  275. 2335  FOR I = 1 TO 37
  276. 2336  FOR J = 1 TO 4
  277. 2337  READ P(I,J)
  278. 2338  NEXT J,I
  279. 2340  LO=33:DIM OB$(LO),OB(LO,1)
  280. 2350  OB$(1)="a set of keys":OB$(2)="a shiny sword"
  281. 2355  DATA 6,0,16,0
  282. 2360  OB$(3)="a parrot in a cage":OB$(4)="a gold nugget"
  283. 2365  DATA 25,5,4,10
  284. 2370  OB$(5)="a 35,000 carat diamond":OB$(6)="a cigarette lighter"
  285. 2375  DATA 7,10,28,0
  286. 2380  OB$(7)="a Quarter":OB$(8)="an enormous emerald"
  287. 2385  DATA 28,0,32,15
  288. 2390  OB$(9)="some silver bars":OB$(10)="a giant hydra with nine heads"
  289. 2395  DATA 33,15,29,0
  290. 2400  OB$(11)="a ming vase":OB$(12)="a bottle of Coke"
  291. 2405  DATA 30,10,0,0
  292. 2410  OB$(13)="an empty Coke bottle":OB$(14)="some tools"
  293. 2415  data 0,0,34,0
  294. 2420  OB$(15)="a large ruby":OB$(16)="gold bars"
  295. 2425  DATA 8,15,19,20
  296. 2430  OB$(17)="a diamond necklace":OB$(18)="a magic wand"
  297. 2435  data 19,25,14,0
  298. 2440  OB$(22)="a Fribulating Gonkulator"
  299. 2445  data 37,50
  300. 2450  OB$(20)="a giant bug asleep"
  301. 2455  DATA 31,0
  302. 2460  OB$(31)="some tasty food":OB$(32)="some human skeletons":OB(32,0)=31
  303. 2465  OB(32,1)=0
  304. 2470  OB$(33)="a dead hydra on the ground"
  305. 2480  FOR I=1 TO 20:READ OB(I,0),OB(I,1):NEXT I
  306. 2490  OB(22,0)=OB(19,0):OB(22,1)=OB(19,1)
  307. 2500  OB(19,1)=0:OB(19,0)=0
  308. 2510  OB(31,0)=27:OB(31,1)=0
  309. 2520  DATA KEYS,SWORD,PARROT,NUGGET,DIAMOND,LIGHTER,QUARTER,EMERALD,SILVER,HYDRA
  310. 2525  data VASE,COKE,BOTTLE,TOOLS,RUBY,GOLD,NECKLACE,WAND,SIGN,BUG,ALEXANDER
  311. 2526  DATA GONKULATOR,NORTH,SOUTH,EAST,WEST
  312. 2530  DATA N,S,E,W,FOOD,SKELETONS
  313. 2540  NN=32:DIM NO$(NN)
  314. 2550  FOR I=1 TO NN:READ NO$(I):NEXT I
  315. 2560  DATA GO,GET,LOOK,INVEN,SCORE,DROP,HELP,SAVE,LOAD,QUIT,SAY,DRINK,FEED,HIT
  316. 2561  DATA KILL,BURN,FIGHT,LIGHT,INSERT,TAKE,WAVE,RELEASE,CONTINUE,DESTROY,SIR
  317. 2562  DATA FIX,EAT,?,INVENTORY,HOCUS
  318. 2570  NV=30:DIM VB$(NV):FOR I=1 TO NV:READ VB$(I):NEXT I
  319. 2580  M1$="The parrot chants: Sir Alexander...Sir Alexander!"
  320. 2590  M2$="The troll scurries away in fear."
  321. 2600  M3$="Gulp gluk gulp! (burp)  That was refreshing!"
  322. 2610  DIM H$(NP)
  323. 2620  H$(25)="This parrot talks..."
  324. 2630  H$(29)="Cigar? Cigarette? Tipparillo?"
  325. 2640  H$(10)="You know this world is enchanted..."
  326. 2650  H$(12)="You can make the passages look less alike by dropping things."
  327. 2660  H$(13)=H$(12):H$(14)=H$(12):H$(15)=H$(12)
  328. 2670  H$(1)="I think we're supposed to leave what we find here."
  329. 2680  H$(35)="Often times oil means an auto bodyshop is nearby."
  330. 2690  H$(31)="The bug will not bother you it is asleep.                                       Hint:  If you linger too long in this room it will wake up!"
  331. 2700  H$(2)="You know, in this enchanted world, many things that                             are small on earth are very large..."
  332. 2710  H$(20)="Try to find your way to the other end, dummy!!":H$(23)=H$(20)
  333. 2720  RETURN
  334. 32000 title$=" A 520ST Adventure "
  335. 32001 poke systab+24,1 : ' Don't need to see this...
  336. 32002 a# = gb : ' Fetch globals address
  337. 32003 gintin = peek(a#+8) : ' AES int_in array
  338. 32004 poke gintin+0,peek(systab+8) : ' OUTPUT window handle
  339. 32005 poke gintin+2,2 : ' we're changing it's name
  340. 32006 s# = gintin+4 : ' DBL address for long poke
  341. 32007 title$ = title$ + chr$(0) : ' assure zero terminator
  342. 32008 poke s#,varptr(title$) : ' title of new window
  343. 32009 gemsys(105) : ' wind_set AES call
  344. 32010 poke systab+24,0 : ' Turn things back on
  345. 32011 return
  346. ə